hispanic: Hispanic ethnicity¶

hispanic title image

Description¶

hispanic indicates whether or not the individual reports Hispanic ethnicity.

Availability¶

Sample	Years
Basic	All years
May	All years
ORG	All years

Warning

This variable is mostly consistent over time, but there are coding changes in 1994, 2003, 2014. See the race/ethnicity methodology for more details.

Values¶

Value	Label
0	Not hispanic
1	Hispanic

Detailed comments¶

Significant race/ethnicity coding changes occur in 1994, 2003, 2014.

In the figure above, 1973-1975 data are from the EPI CPS May extracts, and 1976-2023 data are from the EPI CPS Basic Monthly extracts.

Code¶

Variable creation

********************************************************************************
* Hispanic ethnicity
********************************************************************************
gen byte hispanic = 0

if $marchcps == 1 {
    if tm(1971m1) <= $date & $date <= tm(1997m12) {
        replace hispanic = 1 if 1 <= _spneth & _spneth <= 7
    }
    if tm(1998m1) <= $date & $date <= tm(2002m12) {
        replace hispanic = 1 if 1 <= a_reorgn & a_reorgn <= 7
    }
    if tm(2003m1) <= $date & $date <= tm(2013m12) {
        replace hispanic = 1 if 1 <= prdthsp & prdthsp <= 5
    }
    if tm(2014m1) <= $date {
        replace hispanic = 1 if 1 <= prdthsp & prdthsp <= 8
    }
}

if $monthlycps == 1 | $maycps == 1 {
    if tm(1973m1) <= $date & $date <= tm(1993m12) {
        if tm(1974m1) <= $date & $date <= tm(1988m12) {
            replace spneth = "" if spneth == "A"
            destring spneth, replace
        }
        replace hispanic = 1 if 1 <= spneth & spneth <= 7
    }
    if tm(1994m1) <= $date & $date <= tm(2002m12) {
        replace hispanic = 1 if 1 <= prorigin & prorigin <= 7
    }
    if tm(2003m1) <= $date & $date <= tm(2013m12) {
        replace hispanic = 1 if 1 <= prdthsp & prdthsp <= 5
    }
    if tm(2014m1) <= $date {
        replace hispanic = 1 if 1 <= prdthsp & prdthsp <= 8
    }
}

lab var hispanic "Hispanic ethnicity"
lab define hispanic 0 "Not hispanic" 1 "Hispanic"
lab val hispanic hispanic
notes hispanic: Hispanic ethnicity
notes hispanic: Definition breaks in 1994, 2003, 2014
notes hispanic: not Hispanic includes nonresponse, missing, etc., in order to be consistent with other race variables like wbho
notes hispanic: 1973-1993 Unicon: spneth
notes hispanic: 1994-2002 CPS: prorigin
notes hispanic: 2003-present CPS: prdthsp

Figure creation

keep if age >= 16 & age ~= .

gcollapse (mean) hispanic [pw=basicwgt], by(year) fast
sum year
local maxyear = r(max)

replace hispanic = hispanic * 100
sum hispanic if year == `maxyear'
local hispanicyvalue = r(mean)
local hispanicxvalue = `maxyear' + 0.5

local color1 77 175 74
line hispanic year, ///
legend(off) ///
xlabel(1975(5)2020) ///
ylabel(0(10)40 50 "50%", angle(0) gmin gmax) ///
xtitle("") ytitle("") ///
lcolor("`color1'") ///
graphregion(color(white) margin(r=17)) plotregion(color(white)) ///
title("Hispanic share of population, ages 16 and over", size(medium)) ///
text(`hispanicyvalue' `hispanicxvalue' "Hispanic", color("`color1'") placement(e))
graph export ${variableimages}hispanic_titleimage.svg, replace

/***
Significant race/ethnicity coding changes occur in 1994, 2003, 2014.

In the figure above, 1973-1975 data are from the EPI CPS May extracts, and 1976-2023 data are from the EPI CPS Basic Monthly extracts.
***/