union: Represented by a union as a member or covered by contract

Description

union indicates whether the respondent is represented by a union as a member or covered by contract. See also uncov and unmem.

Availability

Sample	Years
Basic	1984 - present
May	1977 - 1981
ORG	1983 - present

Note

Union status based on both membership and coverage is not available prior to 1977 or in 1982. On the Basic files, union is available 1984 - present.

Values

Value	Label
0	Not union represented
1	Union represented

Code

Variable creation

*******************************************************************************
* Union represented: member or covered
*******************************************************************************
gen byte union = .
replace union = 0 if unmem ~= . | uncov ~= .
replace union = 1 if unmem == 1
replace union = 1 if uncov == 1

* recode as missing in may before 1977 because no union coverage available
if $maycps == 1 {
    if $date <= tm(1976m12) {
        replace union = .
    }
}

* recode as missing in basic before 1984 because no union coverage available
if $monthlycps == 1 & $earnerinfo == 1 & $basicfile == 1 {
    if $date < tm(1984m1) {
        replace union = .
    }
}

* recode as missing in org before 1983 because no union coverage available
if $monthlycps == 1 & $earnerinfo == 1 & $basicfile == 0 {
    if $date < tm(1983m1) {
        replace union = .
    }
}

lab var union "Represented by a union as a member or covered by contract"
lab def union 1 "Union represented" 0 "Not union represented"
lab val union union
notes union: Not defined when union coverage is missing
notes union: Only available in 1977-1981 May, 1983-present ORG
notes union: Not available on 1976-1983 basic monthly files
notes union: Not available prior to 1977 or in 1982
notes union: Derived from unmem and uncov

Figure creation

keep if age >= 16 & selfemp == 0

gen wgt = orgwgt
replace wgt = basicwgt if year < 1983

gcollapse (mean) unmem union [pw=wgt], by(year) fast
foreach var of varlist unmem union {
    replace `var' = `var' * 100
    sum `var' if year == 1977
    local `var'yvalue = r(mean)
    local `var'xvalue = 1977
}

local color1 228 26 28
local color2 55 126 184
local color3 77 175 74
local color4 152 78 163
local color5 255 127 0

local unmemyvalue = `unmemyvalue' - 3
local unionyvalue = `unionyvalue' + 2


line unmem union year if year < 1982, lcolor("`color3'" "`color2'") || ///
line unmem union year if year > 1982, lcolor("`color3'" "`color2'") ///
legend(off) ///
xlabel(1975(5)2020) ///
ylabel(0(5)25 30 "30%", angle(0) gmin gmax) ///
xtitle("") ytitle("") ///
graphregion(color(white)) plotregion(color(white)) ///
title("Union representation and membership as a share of the workforce", size(medium)) ///
text(`unmemyvalue' `unmemxvalue' "Membership", color("`color3'") placement(c)) ///
text(`unionyvalue' `unionxvalue' "Representation", color("`color2'") placement(c))
graph export ${variableimages}union_titleimage.svg, replace