a_weekpay: Weekly pay allocated by BLS

Description

a_weekpay indicates whether or not the weekly earnings variable weekpay is allocated by BLS.

Availability

Sample	Years
ORG	1979 - 1993, 1995m9 - present

Warning

This variable is not consistent over time, with definition changes in January 1989 and September 1995.

There is no allocation information during the January 1994 - August 1995 period.

Values

Value	Label
0	Not allocated
1	Allocated

Code

Variable creation

********************************************************************************
* Weekly earnings allocated by BLS
********************************************************************************
gen byte a_weekpay = .

if $monthlycps == 1 | $maycps == 1 {
    if $earnerinfo == 1 {
        if tm(1979m1) <= $date & $date <= tm(1988m12) {
            replace a_weekpay = 0 if weekpay > 0 & weekpay ~= .
            replace a_weekpay = 1 if aernwk == 1 & weekpay > 0 & weekpay ~= .
            assert a_weekpay ~= . if weekpay > 0 & weekpay ~= .
        }
        if tm(1989m1) <= $date & $date <= tm(1993m12) {
            replace a_weekpay = 0 if weekpay > 0 & weekpay ~= .
            replace a_weekpay = 1 if aernwk >= 1 & aernwk <= 8 & weekpay > 0 & weekpay ~= .
            replace a_weekpay = 1 if ernwk ~= ernwkx & weekpay > 0 & weekpay ~= .
            assert a_weekpay ~= . if weekpay > 0 & weekpay ~= .
        }
        if tm(1995m9) <= $date {
            replace a_weekpay = 0 if weekpay > 0 & weekpay ~= .
            replace a_weekpay = 1 if prwernal == 1 & weekpay > 0 & weekpay ~= .
            assert a_weekpay ~= . if weekpay > 0 & weekpay ~= .
        }
    }
}

lab var a_weekpay "Weekly pay allocated by BLS"
lab def a_weekpay 0 "Not allocated" 1 "Allocated"
lab val a_weekpay a_weekpay
notes a_weekpay: Allocation coding inconsistent across time
notes a_weekpay: No allocation codes available during 1994m1-1995m8

Figure creation

keep if a_weekpay ~= .
keep if age >= 16 & age <= 64
keep if year >= 1979

gcollapse (mean) a_weekpay [pw=orgwgt], by(year) fast

replace a_weekpay = a_weekpay * 100

local color1 228 26 28
local color2 55 126 184
local color3 77 175 74
local color4 152 78 163
local color5 255 127 0

line a_weekpay year if year <= 1988, lcolor("`color4'") || ///
line a_weekpay year if year >= 1989 & year <= 1993, lcolor("`color4'") || ///
line a_weekpay year if year >= 1995, lcolor("`color4'") ///
legend(off) ///
xlabel(1980(5)2020) ///
ylabel(0(10)40 50 "50%", angle(0) gmin gmax) ///
xtitle("") ytitle("") ///
lcolor("`color4'") ///
graphregion(color(white)) plotregion(color(white)) ///
title("Share of workforce with BLS allocated weekly earnings, ages 16-64", size(medsmall))
graph export ${variableimages}a_weekpay_titleimage.svg, replace