paidhre: Paid by hour

Description

paidhre indicates whether or not the respondent is paid by the hour.

Availability

Sample	Years
ORG	1979 - present

Warning

This variable is not consistent over time, with definition changes in 1979 and 1994.

Values

Value	Label
0	Nonhourly worker
1	Hourly worker

Detailed comments

The analysis above uses the CPS ORG for 1979-2023 and the CPS May for 1973-1978.

Code

Variable creation

********************************************************************************
* Paid hourly
********************************************************************************
gen paidhre = .

if $monthlycps == 1 | $maycps == 1 {
    if $earnerinfo == 1 {
        if tm(1973m1) <= $date & $date <= tm(1978m12) {
            replace paidhre = 1 if hourpd == 0
            replace paidhre = 0 if hourpd == 1
        }
        if tm(1979m1) <= $date & $date <= tm(1993m12) {
            replace paidhre = 0 if _ernpdh == 2
            replace paidhre = 1 if _ernpdh == 1
        }
        if tm(1994m1) <= $date {
            replace paidhre = 0 if peernhry == 2
            replace paidhre = 1 if peernhry == 1
        }
    }
}

lab var paidhre "Paid by hour"
lab def paidhre 0 "Nonhourly worker" 1 "Hourly worker"
lab val paidhre paidhre
notes paidhre: Indicates respondent is paid by hour
notes paidhre: Only available in 1973-1978 May and 1979-present ORG
notes paidhre: 1973-1978 Unicon: hourpd
notes paidhre: 1979-1993 Unicon: _ernpdh
notes paidhre: 1994-present CPS: peernhry

Figure creation

keep if paidhre ~= .
keep if age >= 16 & age <= 64

gen wgt = .
replace wgt = basicwgt if year <= 1978
replace wgt = orgwgt if year >= 1979

gcollapse (mean) paidhre_ = paidhre [pw=wgt], by(year female) fast

* make wide and graph
reshape wide paidhre_, i(year) j(female)
foreach var of varlist paidhre_* {
    replace `var' = `var' * 100
    sum `var' if year == 2013
    local `var'yvalue = r(mean)
    local `var'xvalue = 2013
}
local paidhre_0yvalue = `paidhre_0yvalue' - 5
local paidhre_1yvalue = `paidhre_1yvalue' + 5

local color1 228 26 28
local color2 55 126 184
local color3 77 175 74
local color4 152 78 163
local color5 255 127 0

line paidhre_0 paidhre_1 year if year <= 1978, lcolor("`color4'" "`color2'") || ///
line paidhre_0 paidhre_1 year if 1979 <= year & year <= 1993, lcolor("`color4'" "`color2'") || ///
line paidhre_0 paidhre_1 year if 1994 <= year, lcolor("`color4'" "`color2'") ///
legend(off) ///
xlabel(1975(5)2020) ///
ylabel(0(20)80 100 "100%", angle(0) gmin gmax) ///
xtitle("") ytitle("") ///
lcolor("`color4'" "`color2'") ///
graphregion(color(white)) plotregion(color(white)) ///
title("Share of workforce paid by the hour, ages 16-64, by gender", size(medium)) ///
text(`paidhre_0yvalue' `paidhre_0xvalue' "Male", color("`color4'") placement(c)) ///
text(`paidhre_1yvalue' `paidhre_1xvalue' "Female", color("`color2'") placement(c))
graph export ${variableimages}paidhre_titleimage.svg, replace

/***
The analysis above uses the CPS ORG for 1979-2023 and the CPS May for 1973-1978.
***/