Skip to content

selfinc: Incorporated self-employed

selfinc title image

Description

selfinc indicates whether or not the respondent is incorporated self-employed. See also selfemp.

Availability

Sample Years
Basic 1989 - present
ORG 1989 - present

Values

Value Label
0 Not self-employed (incorp)
1 Self-employed (incorp)

Detailed comments

The analysis above uses employed workers in the CPS Basic for 1989-2023.

Code

Variable creation
*******************************************************************************
* Incorporated self-employed
*******************************************************************************
gen byte selfinc = .

if $monthlycps == 1 {
    if tm(1989m1) <= $date & $date <= tm(1993m12) {
        replace selfinc = 0 if class >= 1 & class != .
        replace selfinc = 1 if class == 5
    }
    if tm(1994m1) <= $date {
        replace selfinc = 0 if peio1cow >= 1 & peio1cow != .
        replace selfinc = 1 if peio1cow == 6
    }
}

lab var selfinc "Incorporated self-employed"
lab def selfinc 1 "Self-employed (incorp)" 0 "Not self-employed (incorp)"
lab val selfinc selfinc
notes selfinc: Incorporated self-employed only
notes selfinc: 1994-present CPS: peio1cow
notes selfinc: 1994-present: For first job
notes selfinc: 1989-1993 Unicon: derived from class
notes selfinc: Universe: Class of worker assigned (not necessarily employed)
notes selfinc: Different definitions/universes: 1989-1993, 1994-present
Figure creation
keep if selfinc ~= .
keep if age >= 16 & age <= 64
keep if emp == 1

gcollapse (mean) selfinc_ = selfinc [pw=basicwgt], by(year female) fast

* make wide and graph
reshape wide selfinc_, i(year) j(female)
foreach var of varlist selfinc_* {
    replace `var' = `var' * 100
    sum `var' if year == 2014
    local `var'yvalue = r(mean)
    local `var'xvalue = 2014
}
local selfinc_0yvalue = `selfinc_0yvalue' + 1
local selfinc_1yvalue = `selfinc_1yvalue' - 1

local color1 228 26 28
local color2 55 126 184
local color3 77 175 74
local color4 152 78 163
local color5 255 127 0

line selfinc_0 selfinc_1 year if year <= 1975, lcolor("`color4'" "`color2'") || ///
line selfinc_0 selfinc_1 year if 1976 <= year & year <= 1988, lcolor("`color4'" "`color2'") || ///
line selfinc_0 selfinc_1 year if 1989 <= year & year <= 1993, lcolor("`color4'" "`color2'") || ///
line selfinc_0 selfinc_1 year if 1994 <= year, lcolor("`color4'" "`color2'") ///
legend(off) ///
xlabel(1990(5)2020) ///
ylabel(0(5)20 25 "25%", angle(0) gmin gmax) ///
xtitle("") ytitle("") ///
lcolor("`color4'" "`color2'") ///
graphregion(color(white)) plotregion(color(white)) ///
title("Self-employed share of workforce, ages 16-64, by gender", size(medium)) ///
text(`selfinc_0yvalue' `selfinc_0xvalue' "Male", color("`color4'") placement(c)) ///
text(`selfinc_1yvalue' `selfinc_1xvalue' "Female", color("`color2'") placement(c))
graph export ${variableimages}selfinc_titleimage.svg, replace

/***
The analysis above uses employed workers in the CPS Basic for 1989-2023.
***/