otcrec: Usually receive overtime, tips, commissions

otcrec title image

Description

otcrec indicates whether or not an hourly worker received overtime, tips, or commissions.

Availability

Sample Years
ORG 1994 - present

Detailed comments

The analysis above uses hourly wage earners, ages 16-64,from the CPS ORG for 1994-2019.

Variable creation
********************************************************************************
* Usually receive overtime, tips, commissions 1994-; hourly only
********************************************************************************
* it looks possible to extend the overtime definitions past hourly workers
gen byte otcrec = .

if $monthlycps == 1 | $maycps == 1 {
    if $earnerinfo == 1 {
        if tm(1994m1) <= $date  {
            replace otcrec = 0 if paidhre == 1 & peernuot == 2
            replace otcrec = 1 if paidhre == 1 & peernuot == 1
        }
    }
}

lab var otcrec "Usually receive overtime, tips, commissions"
notes otcrec: Hourly workers only
notes otcrec: 1994-present CPS: derived from peernuot & paidhre
Figure creation
keep if otcrec ~= .
keep if age >= 16 & age <= 64

gcollapse (mean) otcrec_ = otcrec [pw=orgwgt], by(year female) fast

* make wide and graph
reshape wide otcrec_, i(year) j(female)
foreach var of varlist otcrec_* {
    replace `var' = `var' * 100
    sum `var' if year == 2015
    local `var'yvalue = r(mean)
    local `var'xvalue = 2015
}
local otcrec_0yvalue = `otcrec_0yvalue' + 1.5
local otcrec_1yvalue = `otcrec_1yvalue' - 2

local color1 228 26 28
local color2 55 126 184
local color3 77 175 74
local color4 152 78 163
local color5 255 127 0

line otcrec_0 otcrec_1 year, lcolor("`color4'" "`color2'") ///
legend(off) ///
xlabel(1995(5)2015) ///
ylabel(0(5)30 30 "30%", angle(0) gmin gmax) ///
xtitle("") ytitle("") ///
lcolor("`color4'" "`color2'") ///
graphregion(color(white)) plotregion(color(white)) ///
title("Share of hourly earners receiving overtime/tips/commissions", size(medium)) ///
text(`otcrec_0yvalue' `otcrec_0xvalue' "Male", color("`color4'") placement(c)) ///
text(`otcrec_1yvalue' `otcrec_1xvalue' "Female", color("`color2'") placement(c))
graph export ${variableimages}otcrec_titleimage.svg, replace

/***
The analysis above uses hourly wage earners, ages 16-64,from the CPS ORG for 1994-2019.
***/