Skip to content

a_earnhour: Hourly earnings allocated by BLS

a_earnhour title image

Description

a_earnhour indicates whether or not the hourly earnings variable earnhour is allocated by BLS.

Availability

Sample Years
ORG 1979 - 1993, 1995m9 - present

Warning

This variable is not consistent over time, with definition changes in January 1989 and September 1995.

There is no allocation information during the January 1994 - August 1995 period.

Values

Value Label
0 Not allocated
1 Allocated

Code

Variable creation
********************************************************************************
* a_earnhour
* Hourly earnings, for those paid by the hour
* EXcludes overtime, tips, commissions
********************************************************************************
gen a_earnhour = .

if $monthlycps == 1 | $maycps == 1 {
    if $earnerinfo == 1 {
        if tm(1979m1) <= $date & $date <= tm(1988m12) {
            replace a_earnhour = 0 if earnhour > 0 & earnhour ~= .
            replace a_earnhour = 1 if aernhr == 1 & earnhour > 0 & earnhour ~= .
            assert a_earnhour ~= . if earnhour > 0 & earnhour ~= .
        }
        if tm(1989m1) <= $date & $date <= tm(1993m12) {
            replace a_earnhour = 0 if earnhour > 0 & earnhour ~= .
            replace a_earnhour = 1 if aernhr >= 1 & aernhr <= 8 & earnhour > 0 & earnhour ~= .
            replace a_earnhour = 1 if ernhr ~= ernhrx & earnhour > 0 & earnhour ~= .
            assert a_earnhour ~= . if earnhour > 0 & earnhour ~= .
        }
        if tm(1995m9) <= $date {
            replace a_earnhour = 0 if earnhour > 0 & earnhour ~= .
            replace a_earnhour = 1 if prhernal == 1 & earnhour > 0 & earnhour ~= .
            assert a_earnhour ~= . if earnhour > 0 & earnhour ~= .
        }
    }
}

lab var a_earnhour "Hourly earnings allocated by BLS"
lab def a_earnhour 0 "Not allocated" 1 "Allocated"
lab val a_earnhour a_earnhour
notes a_earnhour: Allocation coding inconsistent across time
notes a_earnhour: No allocation codes available during 1994m1-1995m8
Figure creation
keep if a_earnhour ~= .
keep if age >= 16 & age <= 64
keep if year >= 1979

gcollapse (mean) a_earnhour [pw=orgwgt], by(year) fast

replace a_earnhour = a_earnhour * 100

local color1 228 26 28
local color2 55 126 184
local color3 77 175 74
local color4 152 78 163
local color5 255 127 0

line a_earnhour year if year <= 1988, lcolor("`color4'") || ///
line a_earnhour year if year >= 1989 & year <= 1993, lcolor("`color4'") || ///
line a_earnhour year if year >= 1995, lcolor("`color4'") ///
legend(off) ///
xlabel(1980(5)2020) ///
ylabel(0(10)40 50 "50%", angle(0) gmin gmax) ///
xtitle("") ytitle("") ///
lcolor("`color4'") ///
graphregion(color(white)) plotregion(color(white)) ///
title("Share of workforce with BLS allocated hourly earnings, ages 16-64", size(medsmall))
graph export ${variableimages}a_earnhour_titleimage.svg, replace